(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: Number.m3                                             *)
(* Last Modified On Tue Mar 20 03:19:49 1990 By muller         *)
(*      Modified On Fri Jul 14 17:22:43 1989 By kalsow         *)

MODULE Number;

IMPORT CallExpr, Expr, Type, Procedure, Card, Error, First;
IMPORT ArrayType, Emit, TypeExpr, IntegerExpr, Temp;

VAR
  Z: CallExpr.MethodList;


PROCEDURE Bind (<*UNUSED*> proc: Expr.T; <*UNUSED*> args: Expr.List): Type.T =
  BEGIN
    RETURN Card.T;
  END Bind;

PROCEDURE Check (<*UNUSED*> proc: Expr.T; VAR args: Expr.List) =
  BEGIN
    First.DoCheck ("NUMBER", args);
  END Check;

PROCEDURE Compile (<*UNUSED*> proc: Expr.T; args: Expr.List): Temp.T =
  VAR e: Expr.T; t, index, element: Type.T; min, max: INTEGER; t1, t2: Temp.T;
  BEGIN
    e := args[0];
    t := Expr.TypeOf (e);
    t1 := Temp.AllocEmpty (Card.T);
    IF ArrayType.Split (t, index, element) THEN
      IF (index = NIL) THEN
        t2 := Expr.Compile (e);
        Emit.OpTT ("@ = @.size[0];\n", t1, t2);
        Temp.Free (t2);
        RETURN t1;
      END;
    ELSE
      VAR b: BOOLEAN := TypeExpr.Split (e, index);
      BEGIN <* ASSERT b *> END;
      IF ArrayType.Split (index, index, element) THEN END;
    END;
    Type.GetBounds (index, min, max);
    IF (min > max) THEN max := min - 1 END;
    IF (min < 0) AND (min + LAST (INTEGER) <= max) THEN
      Error.Msg ("result of NUMBER too large");
    END;
    Emit.OpTI ("@ = @;\n", t1, max - min + 1);
    RETURN t1;
  END Compile;

PROCEDURE Fold (<*UNUSED*> proc: Expr.T; args: Expr.List): Expr.T =
  VAR t, elem: Type.T; min, max: INTEGER;
  BEGIN
    IF TypeExpr.Split (args[0], t) THEN
      IF ArrayType.Split (t, t, elem) AND (t = NIL) THEN RETURN NIL END;
    ELSE
      IF ArrayType.Split (Expr.TypeOf (args[0]), t, elem) THEN
        IF (t = NIL) THEN RETURN NIL; END;
      ELSE (* expr is not an array *)
        RETURN NIL;
      END;
    END;
    Type.GetBounds (t, min, max);
    IF (min > max) THEN max := min - 1 END;
    IF (min < 0) AND (min + LAST (INTEGER) <= max) THEN
      Error.Msg ("result of NUMBER too large");
      max := min + 1;
    END;
    RETURN IntegerExpr.New (max - min + 1);
  END Fold;

PROCEDURE Initialize () =
  BEGIN
    Z := CallExpr.NewMethodList (1, 1, TRUE, Bind, Check, Compile, Fold,
                                 CallExpr.IsNever, (* writable *)
                                 CallExpr.IsNever(* designator *));
    Procedure.Define ("NUMBER", Z);
  END Initialize;

BEGIN
END Number.