(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: WordGE.m3                                             *)
(* Last Modified On Tue Apr 10 11:10:31 1990 By muller         *)
(*      Modified On Fri Aug  4 09:28:19 1989 By kalsow         *)


MODULE WordGE;

IMPORT Word, CallExpr, Expr, Type, Procedure, Emit, Temp;
IMPORT Bool, WordPlus, Value, Formal, BuiltinArgs, ProcType;

VAR
  Z: CallExpr.MethodList;
  formals: ARRAY [0..1] OF Value.T;

PROCEDURE Bind (<*UNUSED*> proc: Expr.T; <*UNUSED*> args: Expr.List): Type.T =
  BEGIN
    RETURN Bool.T;
  END Bind;

PROCEDURE Check (<*UNUSED*> proc: Expr.T; VAR args: Expr.List) =
  BEGIN
    IF Formal.CheckArgs (args, formals) THEN END;
  END Check;

PROCEDURE Compile (<*UNUSED*> proc: Expr.T; args: Expr.List): Temp.T =
  VAR t1, t2, t3: Temp.T;
  BEGIN
    t1 := Expr.Compile (args[0]);
    t2 := Expr.Compile (args[1]);
    t3 := Temp.AllocEmpty (Bool.T);
    Emit.OpTTT ("@ = (unsigned)@ >= (unsigned)@;\n", t3, t1, t2);
    Temp.Free (t1);
    Temp.Free (t2);
    RETURN t3;
  END Compile;

PROCEDURE Fold (<*UNUSED*> proc: Expr.T; args: Expr.List): Expr.T =
  VAR w0, w1: Word.T;
  BEGIN
    IF WordPlus.GetArgs (args, w0, w1)
      THEN RETURN Bool.Map[Word.GE (w0, w1)];
      ELSE RETURN NIL;
    END;
  END Fold;

PROCEDURE Initialize () =
  BEGIN
    formals[0] := BuiltinArgs.f1;
    formals[1] := BuiltinArgs.f5;
    Z := CallExpr.NewMethodList (2, 2, TRUE, Bind, Check, Compile, Fold,
                                 CallExpr.IsNever, (* writable *)
                                 CallExpr.IsNever(* designator *));
    Procedure.Define ("GE", Z, ProcType.New (formals, Bool.T));
  END Initialize;

BEGIN
END WordGE.