(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: WordNot.m3                                            *)
(* Last Modified On Tue Apr 10 11:15:33 1990 By muller         *)
(*      Modified On Fri Aug  4 09:38:20 1989 By kalsow         *)


MODULE WordNot;

IMPORT Word, CallExpr, Expr, Type, Procedure, Emit, Temp;
IMPORT Int, IntegerExpr, Value, Formal, BuiltinArgs, ProcType;

VAR
  Z: CallExpr.MethodList;
  formals: ARRAY [0..0] OF Value.T;

PROCEDURE Bind (<*UNUSED*> proc: Expr.T; <*UNUSED*> args: Expr.List): Type.T =
  BEGIN
    RETURN Int.T;
  END Bind;

PROCEDURE Check (<*UNUSED*> proc: Expr.T; VAR args: Expr.List) =
  BEGIN
    IF Formal.CheckArgs (args, formals) THEN END;
  END Check;

PROCEDURE Compile (<*UNUSED*> proc: Expr.T; args: Expr.List): Temp.T =
  VAR t1, t2: Temp.T;
  BEGIN
    t1 := Expr.Compile (args[0]);
    t2 := Temp.AllocEmpty (Int.T);
    Emit.OpTT ("@ = ~ @;\n", t2, t1);
    Temp.Free (t1);
    RETURN t2;
  END Compile;

PROCEDURE Fold (<*UNUSED*> proc: Expr.T; args: Expr.List): Expr.T =
  VAR e: Expr.T;  w: Word.T;
  BEGIN
    e := Expr.ConstValue (args[0]);
    IF (e # NIL) AND IntegerExpr.Split (e, w)
      THEN RETURN IntegerExpr.New (Word.Not (w));
      ELSE RETURN NIL;
    END;
  END Fold;

PROCEDURE Initialize () =
  BEGIN
    formals[0] := BuiltinArgs.f1;
    Z := CallExpr.NewMethodList (1, 1, TRUE, Bind, Check, Compile, Fold,
                                 CallExpr.IsNever, (* writable *)
                                 CallExpr.IsNever(* designator *));
    Procedure.Define ("Not", Z, ProcType.New (formals, Int.T));
  END Initialize;

BEGIN
END WordNot.