(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: CheckExpr.m3                                          *)
(* Last Modified On Sat Feb 10 20:01:03 1990 By kalsow         *)
(*      Modified On Tue Oct 10 18:42:59 1989 By muller         *)

MODULE CheckExpr;

IMPORT Expr, ExprRep, Type, Emit, IntegerExpr, EnumExpr, Temp, Wr, Fmt;

TYPE
  Class = { cLOWER, cUPPER, cBOTH };

TYPE
  P = Expr.T OBJECT
        expr  : Expr.T;
        min   : INTEGER;
        max   : INTEGER;
        class : Class;
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := EqCheck;
        getBounds    := Bounder;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a: Expr.T;  min, max: INTEGER): Expr.T =
  BEGIN
    RETURN Create (a, min, max, Class.cBOTH);
  END New;

PROCEDURE NewLower (a: Expr.T;  min: INTEGER): Expr.T =
  BEGIN
    RETURN Create (a, min, 0, Class.cLOWER);
  END NewLower;

PROCEDURE NewUpper (a: Expr.T;  max: INTEGER): Expr.T =
  BEGIN
    RETURN Create (a, 0, max, Class.cUPPER);
  END NewUpper;

PROCEDURE Create (a: Expr.T;  min, max: INTEGER;  c: Class): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.expr  := a;
    p.min   := min;
    p.max   := max;
    p.class := c;
    RETURN p;
  END Create;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.expr);
    p.type := Expr.TypeOf (p.expr);
  END Bind;

PROCEDURE Check (p: P) =
  BEGIN
    Expr.TypeCheck (p.expr);
  END Check;

PROCEDURE EqCheck (a: P;  e: Expr.T): BOOLEAN =
  BEGIN
    TYPECASE e OF
    | NULL => RETURN FALSE;
    | P(b) => RETURN (a.class = b.class)
                 AND (a.min = b.min)
                 AND (a.max = b.max)
                 AND Expr.IsEqual (a.expr, b.expr);
    ELSE RETURN FALSE;
    END;
  END EqCheck;

PROCEDURE Compile (p: P): Temp.T =
  VAR t1, t2: Temp.T;
  BEGIN
    t1 := Expr.Compile (p.expr);
    t2 := Temp.Alloc (p);
    Emit.OpTT ("@ = @;\nif (", t2, t1);
    CASE p.class OF
    | Class.cLOWER => Emit.OpTI ("@ < @", t2, p.min);
    | Class.cUPPER => Emit.OpTI ("@ > @", t2, p.max);
    | Class.cBOTH  => Emit.OpTI ("(@ < @) ", t2, p.min);
                      Emit.OpIT ("|| (@ < @)", p.max, t2);
    END;
    Emit.Op (") RANGEFAULT;\n");
    Temp.Free (t1);
    RETURN t2;
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  VAR e: Expr.T;  i: INTEGER;  t: Type.T;
  BEGIN
    e := Expr.ConstValue (p.expr);
    IF (e = NIL) THEN RETURN NIL END;
    IF (NOT IntegerExpr.Split (e, i))
      AND (NOT EnumExpr.Split (e, i, t)) THEN
      RETURN NIL;
    END;
    CASE p.class OF
    | Class.cLOWER => IF (p.min > i) THEN RETURN NIL END;
    | Class.cUPPER => IF (p.max < i) THEN RETURN NIL END;
    | Class.cBOTH  => IF (i < p.min) OR (p.max < i) THEN RETURN NIL END;
    END;
    RETURN e;
  END Fold;

PROCEDURE Bounder (p: P;  VAR min, max: INTEGER) =
  BEGIN
    Expr.GetBounds (p.expr, min, max);
    CASE p.class OF
    | Class.cLOWER => min := MAX (min, p.min);
    | Class.cUPPER => max := MIN (max, p.max);
    | Class.cBOTH  => min := MAX (min, p.min);  max := MIN (max, p.max);
    END;
  END Bounder;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    CASE p.class OF
    | Class.cLOWER => Wr.PutText (wr, "CHKL " & Fmt.Int (p.min) & " ");
    | Class.cUPPER => Wr.PutText (wr, "CHKH " & Fmt.Int (p.max) & " ");
    | Class.cBOTH  => Wr.PutText (wr, "CHKR " & Fmt.Int (p.min) & " "
                                              & Fmt.Int (p.max) & " ");
    END;
    Expr.Fingerprint (p.expr, map, wr);
  END FPrinter;

BEGIN
END CheckExpr.