(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: ConcatExpr.m3                                         *)
(* Last modified on Sat Feb 10 17:32:54 1990 by kalsow         *)
(*      modified on Mon Jan 22 05:30:18 1990 by muller         *)


MODULE ConcatExpr;

IMPORT Expr, ExprAB, ExprRep, Type, Textt, Error;
IMPORT String, Emit, TextExpr, Temp, Wr;

TYPE
  P = ExprAB.T OBJECT
        const : Expr.T;
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := ExprAB.EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a, b: Expr.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.a := a;
    p.b := b;
    p.const := NIL;
    p.type := Textt.T;
    RETURN p;
  END New;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.a);
    Expr.Bind (p.b);
    EVAL Fold (p); (* try folding all concatenations *)
  END Bind;

PROCEDURE Check (p: P) =
  VAR ta, tb: Type.T;
  BEGIN
    IF (p.const # NIL) THEN
      Expr.TypeCheck (p.const);
    ELSE
      Expr.TypeCheck (p.a);
      Expr.TypeCheck (p.b);
      ta := Type.Base (Expr.TypeOf (p.a));
      tb := Type.Base (Expr.TypeOf (p.b));
      IF (ta # Textt.T) OR (tb # Textt.T) THEN
        Error.Msg ("illegal operands for \'&\'");
      END;
    END;
  END Check;

PROCEDURE Compile (p: P): Temp.T =
  VAR t1, t2, t3: Temp.T;
  BEGIN
    IF (p.const # NIL) THEN
      t3 := Expr.Compile (p.const);
    ELSE
      <* ASSERT p.a # NIL *>
      t1 := Expr.Compile (p.a);
      <* ASSERT t1 # NIL *>
      <* ASSERT p.b # NIL *>
      t2 := Expr.Compile (p.b);
      <* ASSERT t2 # NIL *>
      t3 := Temp.Alloc (p);
      Emit.OpTTT ("@ = (ADDRESS) _Text__Cat (@, @);\n", t3, t1, t2);
      Temp.Free (t1);
      Temp.Free (t2);
    END;
    RETURN t3;
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  VAR e1, e2, e3: Expr.T;
  BEGIN
    IF (p.const # NIL) THEN RETURN p.const END;
    e1 := Expr.ConstValue (p.a);
    IF (e1 = NIL) THEN RETURN NIL END;
    p.a := e1;
    e2 := Expr.ConstValue (p.b);
    IF (e2 = NIL) THEN RETURN NIL END;
    p.b := e2;
    e3 := NIL;
    IF TextExpr.Cat (e1, e2, e3) THEN p.const := e3 END;
    RETURN e3;
  END Fold;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "& ");
    Expr.Fingerprint (p.a, map, wr);
    Expr.Fingerprint (p.b, map, wr);
  END FPrinter;

BEGIN
END ConcatExpr.