(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: DerefExpr.m3                                          *)
(* Last modified on Thu Jun 28 03:42:29 1990 by muller         *)
(*      modified on Sat Feb 10 20:04:50 1990 by kalsow         *)


MODULE DerefExpr;

IMPORT Expr, ExprA, ExprRep, RefType, Error, Type, Emit;
IMPORT Temp, Void, NilChkExpr, Wr;

TYPE
  P = ExprA.T OBJECT
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := ExprRep.NoValue;
        fprint       := FPrinter;
        write        := Writer;
        isEqual      := ExprA.EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsAlways;
        isDesignator := ExprRep.IsAlways;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a: Expr.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.a := NilChkExpr.New (a);
    RETURN p;
  END New;

PROCEDURE SetOffset (e: Expr.T; n: INTEGER) =
  BEGIN
    TYPECASE e OF
    | NULL => (* nothing *)
    | P(p) => NilChkExpr.SetOffset (p.a, n);
    ELSE      (* nothing *)
    END;
  END SetOffset;

PROCEDURE Bind (p: P) =
  VAR ta, target: Type.T;
  BEGIN
    Expr.Bind (p.a);
    ta := Type.Base (Expr.TypeOf (p.a));
    target := Void.T;
    IF NOT RefType.Split (ta, target) THEN
      Error.Msg ("cannot dereference a non-REF value");
    ELSIF (target = NIL) THEN
      Error.Msg ("cannot dereference an open REF type");
    END;
    p.type := target;
  END Bind;

PROCEDURE Check (p: P) =
  BEGIN
    Expr.TypeCheck (p.a);
  END Check;

PROCEDURE Compile (p: P): Temp.T =
  VAR t1, t2: Temp.T;
  BEGIN
    t1 := Expr.Compile (p.a);
    t2 := Temp.AllocMacro (p, TRUE);
    Temp.Depend (t2, t1);
    RETURN t2;
  END Compile;

PROCEDURE Writer (p: P;  t1: Temp.T; <*UNUSED*> t2: Temp.T) =
  BEGIN
    Emit.OpIT ("(*((t@*) @))", Type.Name (p.type), t1);
  END Writer;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "^ ");
    Expr.Fingerprint (p.a, map, wr);
  END FPrinter;

BEGIN
END DerefExpr.