(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: InExpr.m3                                             *)
(* Last modified on Sun Jun  3 07:39:02 1990 by muller         *)
(*      modified on Sat Feb 10 17:36:38 1990 by kalsow         *)


MODULE InExpr;

IMPORT Expr, ExprAB, ExprRep, Error, Type, SetType, Bool, Emit;
IMPORT SetExpr, IntegerExpr, EnumExpr, Temp, Wr, SubrangeType;

TYPE
  P = ExprAB.T OBJECT
      METHODS
        bind         := ExprAB.Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := ExprAB.EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a, b: Expr.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.a    := a;
    p.b    := b;
    p.type := Bool.T;
    RETURN p;
  END New;

PROCEDURE Check (p: P) =
  VAR ta, tb, tc: Type.T;
  BEGIN
    Expr.TypeCheck (p.a);
    Expr.TypeCheck (p.b);
    ta := Type.Base (Expr.TypeOf (p.a));
    tb := Type.Base (Expr.TypeOf (p.b));
    IF NOT SetType.Split (tb, tc) THEN
      Error.Msg ("second operand of IN must be a set");
    ELSIF NOT Type.IsSubtype (ta, Type.Base (tc)) THEN
      Error.Msg ("operands of IN are incompatible");
    END;
  END Check;

PROCEDURE Compile (p: P): Temp.T =
  VAR t3: Temp.T;
  BEGIN
    t3 := Temp.Alloc (p);
    SetExpr.CompileMember (p.b, p.a, t3, p.b.type);
    RETURN t3;
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  VAR e1, e2, e3: Expr.T;
  BEGIN
    e1 := Expr.ConstValue (p.b);
    e2 := Expr.ConstValue (p.a);
    e3 := NIL;
    IF (e1 = NIL) OR (e2 = NIL) THEN
    ELSIF SetExpr.Member (e1, e2, e3) THEN
    END;
    RETURN e3;
  END Fold;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "IN ");
    Expr.Fingerprint (p.a, map, wr);
    Expr.Fingerprint (p.b, map, wr);
  END FPrinter;

BEGIN
END InExpr.