(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: NegateExpr.m3                                         *)
(* Last modified on Sat Feb 10 17:40:17 1990 by kalsow         *)
(*      modified on Tue Oct 10 18:42:30 1989 by muller         *)

MODULE NegateExpr;

IMPORT Expr, ExprA, ExprRep, Type, Error, Int, Reel, Longreal;
IMPORT IntegerExpr, RealExpr, LongrealExpr, Temp, Wr, Emit;

TYPE
  P = ExprA.T OBJECT
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := ExprA.EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a: Expr.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.a := a;
    RETURN p;
  END New;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.a);
    p.type := Type.Base (Expr.TypeOf (p.a));
  END Bind;

PROCEDURE Check (p: P) =
  VAR ta: Type.T;
  BEGIN
    Expr.TypeCheck (p.a);
    ta := Type.Base (Expr.TypeOf (p.a));
    IF (ta # Int.T) AND (ta # Reel.T) AND (ta # Longreal.T) THEN
      Error.Msg ("illegal operands for unary \'-\'");
    END;
  END Check;

PROCEDURE Compile (p: P): Temp.T =
  VAR t1, t2: Temp.T;
  BEGIN
    t1 := Expr.Compile (p.a);
    t2 := Temp.Alloc (p);
    Emit.OpTT ("@ = - @;\n", t2, t1);
    Temp.Free (t1);
    RETURN t2;
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  VAR e1, e3: Expr.T;
  BEGIN
    e1 := Expr.ConstValue (p.a);
    e3 := NIL;
    IF (e1 = NIL) THEN
    ELSIF IntegerExpr.Negate (e1, e3) THEN
    ELSIF RealExpr.Negate (e1, e3) THEN
    ELSIF LongrealExpr.Negate (e1, e3) THEN
    END;
    RETURN e3;
  END Fold;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "U- ");
    Expr.Fingerprint (p.a, map, wr);
  END FPrinter;

BEGIN
END NegateExpr.