(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: PlusExpr.m3                                           *)
(* Last modified on Sat Feb 10 17:41:57 1990 by kalsow         *)
(*      modified on Tue Oct 10 18:42:25 1989 by muller         *)

MODULE PlusExpr;

IMPORT Expr, ExprA, ExprRep, Type, Error, Int, Reel, Longreal, Temp, Wr;

TYPE
  P = ExprA.T OBJECT
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a: Expr.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.a := a;
    RETURN p;
  END New;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.a);
    p.type := Expr.TypeOf (p.a);
  END Bind;

PROCEDURE Check (p: P) =
  VAR t: Type.T;
  BEGIN
    Expr.TypeCheck (p.a);
    t := Type.Base (p.type);
    IF (t # Int.T) AND (t # Reel.T) AND (t # Longreal.T) THEN
      Error.Msg ("illegal operands for unary \'+\'");
    END;
  END Check;

PROCEDURE EqCheck (a: P;  e: Expr.T): BOOLEAN =
  BEGIN
    TYPECASE e OF
    | NULL => RETURN FALSE;
    | P(b) => RETURN Expr.IsEqual (a.a, b.a);
    ELSE      RETURN Expr.IsEqual (a.a, e);
    END;
  END EqCheck;

PROCEDURE Compile (p: P): Temp.T =
  BEGIN
    RETURN Expr.Compile (p.a);
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  BEGIN
    RETURN Expr.ConstValue (p.a);
  END Fold;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "U+ ");
    Expr.Fingerprint (p.a, map, wr);
  END FPrinter;

BEGIN
END PlusExpr.