(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: ProcCheckExpr.m3                                      *)
(* Last Modified On Sat Feb 10 17:41:57 1990 By kalsow         *)

MODULE ProcCheckExpr;

IMPORT Expr, ExprA, ExprRep, Type, Emit, ProcExpr, Temp, Wr, Value, Procedure;

TYPE
  P = ExprA.T OBJECT
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := Fold;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := ExprA.EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := ExprRep.NoLiteral;
      END;

PROCEDURE New (a: Expr.T): Expr.T =
  VAR p := NEW (P);
  BEGIN
    ExprRep.Init (p);
    p.a := a;
    RETURN p;
  END New;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.a);
    p.type := Expr.TypeOf (p.a);
  END Bind;

PROCEDURE Check (p: P) =
  VAR e: Expr.T;
  BEGIN
    e := p.a;
    Expr.TypeCheck (e);
  END Check;

PROCEDURE Compile (p: P): Temp.T =
  VAR t1, t2: Temp.T;
  BEGIN
    t1 := Expr.Compile (p.a);
    t2 := Temp.Alloc (p);
    Emit.OpTT ("@ = @;\n", t2, t1);
    Emit.OpT ("if (IS_CLOSURE (@)) NARROWFAULT;\n", t2);
    Temp.Free (t1);
    RETURN t2;
  END Compile;

PROCEDURE Fold (p: P): Expr.T =
  VAR e: Expr.T;  proc: Value.T;
  BEGIN
    e := Expr.ConstValue (p.a);
    IF (e = NIL) THEN RETURN NIL END;
    IF  NOT ProcExpr.Split (e, proc) THEN RETURN NIL END;
    IF Procedure.IsNested (proc) THEN RETURN NIL END;
    RETURN e;
  END Fold;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Wr.PutText (wr, "CHKP ");
    Expr.Fingerprint (p.a, map, wr);
  END FPrinter;

BEGIN
END ProcCheckExpr.