(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: ProcExpr.m3                                           *)
(* Last modified on Sat Feb 10 17:41:57 1990 by kalsow         *)
(*      modified on Tue Oct 10 18:42:24 1989 by muller         *)

MODULE ProcExpr;

IMPORT Expr, ExprRep, Type, Value, ValueRep, Temp, Wr, Emit;

TYPE
  P = Expr.T OBJECT
        proc : Value.T;
      METHODS
        bind         := Bind;
        check        := Check;
        compile      := Compile;
        evaluate     := ExprRep.Self;
        fprint       := FPrinter;
        write        := ExprRep.NoWriter;
        isEqual      := EqCheck;
        getBounds    := ExprRep.NoBounds;
        isWritable   := ExprRep.IsNever;
        isDesignator := ExprRep.IsNever;
	isZeroes     := ExprRep.IsNever;
	genLiteral   := GenLiteral;
      END;

PROCEDURE New (proc: Value.T): Expr.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    ExprRep.Init (p);
    p.proc    := proc;
    p.bound   := proc.bound;
    p.checked := proc.checked;
    p.type    := proc.type;
    RETURN p;
  END New;

PROCEDURE Split (e: Expr.T;  VAR proc: Value.T): BOOLEAN =
  BEGIN
    TYPECASE e OF
    | NULL => RETURN FALSE;
    | P(p) => proc := p.proc; RETURN TRUE;
    ELSE      RETURN FALSE;
    END;
  END Split;

PROCEDURE Compare (a, b: Expr.T;  VAR sign: INTEGER): BOOLEAN =
  VAR x, y: Value.T;
  BEGIN
    TYPECASE a OF
    | NULL => RETURN FALSE;
    | P(p) => x := p.proc;
    ELSE      RETURN FALSE;
    END;
    TYPECASE b OF
    | NULL => RETURN FALSE;
    | P(p) => y := p.proc;
    ELSE      RETURN FALSE;
    END;
    IF (x = y) THEN sign := 0 ELSE sign :=  -3 END;
    RETURN TRUE;
  END Compare;

PROCEDURE Bind (p: P) =
  BEGIN
    Value.Bind (p.proc);
    p.type := Value.TypeOf (p.proc);
  END Bind;

PROCEDURE Check (p: P) =
  BEGIN
    Value.TypeCheck (p.proc);
  END Check;

PROCEDURE EqCheck (a: P;  e: Expr.T): BOOLEAN =
  BEGIN
    TYPECASE e OF
    | NULL => RETURN FALSE;
    | P(b) => RETURN (a.proc = b.proc);
    ELSE      RETURN FALSE;
    END;
  END EqCheck;

PROCEDURE Compile (p: P): Temp.T =
  BEGIN
    RETURN Value.Load (p.proc);
  END Compile;

PROCEDURE FPrinter (p: P;  map: Type.Map;  wr: Wr.T) =
  BEGIN
    Value.Fingerprint (p.proc, map, wr)
  END FPrinter;

PROCEDURE GenLiteral (p: P) =
  BEGIN
    Emit.OpN ("@", p.proc);
  END GenLiteral;

BEGIN
END ProcExpr.