(* Copyright (C) 1989, Digital Equipment Corporation           *)
(* All rights reserved.                                        *)
(* See the file COPYRIGHT for a full description.              *)

(* File: EvalStmt.m3                                           *)
(* Last modified on Tue Apr 10 22:53:33 1990 by muller         *)
(*      modified on Sat Feb 10 20:37:27 1990 by kalsow         *)


MODULE EvalStmt;

IMPORT Expr, Token, Scanner, Stmt, StmtRep, Error, Temp, Void, Type;

TYPE
  P = Stmt.T OBJECT
        e          : Expr.T;
      METHODS
	bind       := Bind;
        check      := Check;
	precompile := Precompile;
	compile    := Compile;
      END;

PROCEDURE Parse (READONLY fail: Token.Set): Stmt.T =
  VAR p: P;
  BEGIN
    p := NEW (P);
    StmtRep.Init (p);
    Scanner.Match (Token.T.tEVAL, fail, Token.ExprStart);
    p.e := Expr.Parse (fail);
    RETURN p;
  END Parse;

PROCEDURE Bind (p: P) =
  BEGIN
    Expr.Bind (p.e);
  END Bind;

PROCEDURE Check (p: P) =
  BEGIN
    Expr.TypeCheck (p.e);
    IF Type.IsEqual (Expr.TypeOf (p.e), Void.T) THEN
      Error.Msg ("expression doesn\'t have a value");
    END;
  END Check;

PROCEDURE Precompile (<*UNUSED*> p: P) =
  BEGIN
  END Precompile;

PROCEDURE Compile (p: P): Stmt.Outcomes =
  VAR t: Temp.T;
  BEGIN
    t := Expr.Compile (p.e);
    Temp.Free (t);
    RETURN Stmt.Outcomes {Stmt.Outcome.FallThrough};
  END Compile;

BEGIN
END EvalStmt.